CREATE TABLE tblBox
(
  BoxId INT IDENTITY PRIMARY KEY
 ,Length INT NOT NULL
 ,Width INT NOT NULL
 ,Height INT NOT NULL
)

CREATE TABLE tblConstraint
(
  ConstraintId INT IDENTITY PRIMARY KEY
 ,Formula VARCHAR( 500 ) NOT NULL
)

INSERT
  INTO tblBox
       ( Length
        ,Width
        ,Height
       )
  VALUES ( 5, 15, 20 )
        ,( 10, 25, 4 )
        ,( 100, 100, 100 )

INSERT
  INTO tblConstraint
       ( Formula
       )
  VALUES ( '( Length + Width ) * 2 <= 50' )
        ,( 'Width <= 75' )
        ,( 'Length * Width * Height <= 1200' )

use tempdb;
go

create table dbo.tblBox
(
  BoxId int identity primary key,
  Length int not null,
  Width int not null,
  Height int not null
);

create table dbo.tblConstraint
(
  ConstraintId int identity primary key,
  Formula varchar(500) not null
);
go

create function dbo.fnEvaluateConstraints
(
 @Length int,
 @Width int,
 @Height int
)
returns table
as
return (
 select cast(null as int) as ConstraintId, cast(null as bit) as Successfully where 1 = 0
);
go

create trigger dbo.trBuildEvaluationConstraintsFunction
on dbo.tblConstraint
with execute as 'dbo'
for insert, update, delete
as
begin
 set nocount on;

 if not exists(select 1 from inserted) and not exists(select 1 from deleted)
  return;

 declare @s varchar(max);

 with t(x) as
 (
  select
   ' union all select ' + cast(ConstraintId as varchar(10)) + ' as ConstraintId, cast(case when ' + a.Predicates + ' then 1 else 0 end as bit) as Successfully'
  from
   dbo.tblConstraint with (tablock) cross apply
   (select replace(replace(replace(Formula, 'Length', '@Length'), 'Width', '@Width'), 'Height', '@Height')) a(Predicates)
  for xml path(''), type
 )
 select
  @s = stuff(x.value('.', 'varchar(max)'), 1, len(' union all '), '')
 from
  t;

 if @s is not null
  select @s = 'alter function dbo.fnEvaluateConstraints(@Length int, @Width int, @Height int) returns table as return (' + @s + ');'
 else
  select @s = 'alter function dbo.fnEvaluateConstraints(@Length int, @Width int, @Height int) returns table as return (select cast(null as int) as ConstraintId, cast(null as bit) as Successfully where 1 = 0);'

 exec(@s);
end;
go

insert into dbo.tblBox
 (Length, Width, Height)
values
 (5, 15, 20),
 (10, 25, 4 ),
 (100, 100, 100);

insert into dbo.tblConstraint
 (Formula)
values
 ('( Length + Width ) * 2 <= 50'),
 ('Width <= 75'),
 ('Length * Width * Height <= 1200');
go

select
 b.BoxId, c.ConstraintId
from
 dbo.tblBox b cross apply
 dbo.fnEvaluateConstraints(b.Length, b.Width, b.Height) c
where
 c.Successfully = 0;
go

drop function dbo.fnEvaluateConstraints;
drop table dbo.tblBox, dbo.tblConstraint;
go