use tempdb;
go

create type dbo.tTable as table
(
 id int
);
go

create procedure dbo.spTest
 @t dbo.tTable readonly
as
begin
 select * from @t;
end;
go

create function dbo.fnTest
(
 @t dbo.tTable readonly
)
returns table
as
return (select * from @t);
go

create procedure dbo.spTest2
as
begin
 declare @t dbo.tTable;
 select * from @t;
end;
go

declare @v dbo.tTable;
exec dbo.spTest @v;
select * from dbo.fnTest(@v);
go

create type dbo.tTableNew as table
(
 id int,
 v int
);
go

exec sp_rename 'dbo.tTable', 'tTableOld';
exec sp_rename 'dbo.tTableNew', 'tTable';
go

declare @s varchar(max);

select @s = (
 select
  'exec sp_refreshsqlmodule ' + quotename(quotename(referencing_schema_name) + '.' + quotename(referencing_entity_name), '''') + '; '
 from
  sys.dm_sql_referencing_entities('dbo.tTable', 'type')
 for xml path(''), type
).value('.', 'varchar(max)');
exec(@s);
go

drop type dbo.tTableOld;
go

declare @v dbo.tTable;
exec dbo.spTest @v;
exec dbo.spTest2;
select * from dbo.fnTest(@v);
go

drop procedure dbo.spTest, dbo.spTest2;
drop function dbo.fnTest;
drop type dbo.tTable;
go