IF OBJECT_ID( 'tempdb..#t' ) IS NOT NULL
  DROP TABLE #t
;
CREATE TABLE #t( 
  [client_id] INT,
  [d_start] DATE,
  [d_finish] DATE,
  [product] NVARCHAR(100) )
;
INSERT
INTO
  #t
VALUES
  ( 1, '20100101', '20101231', 'товар №1' ),
  ( 1, '20100601', '20110630', 'товар №2' ),
  ( 1, '20110720', '20111231', 'товар №3' ), -- разрыв в 20 дней, но это не считаем разрывом, т.к. это меньше 30 дней.
  ( 1, '20120215', '20140228', 'товар №4' ), -- разрыв №1, 15.02.2012 -дата, когда клиент возобновил пользование нашими услугами после разрыва.
  ( 1, '20140101', '20141231', 'товар №5' ),
  ( 1, '20160101', '20161231', 'товар №6' )  -- разрыв №2, 01.01.2016 -дата, когда клиент возобновил пользование нашими услугами после разрыва. 
;
WITH
h1 AS (
  SELECT
    [client_id],
    [is_end] = 0,
    [dt] = [d_start]
  FROM
    #t
  UNION ALL
  SELECT
    [client_id],
    [is_end] = 1,
    [dt] = [d_finish]
  FROM
    #t
),
h2 AS (
  SELECT
    *,
    [is_open] = SUM( CASE 
                  WHEN [is_end] = 0 THEN 1 
                  WHEN [is_end] = 1 THEN -1 
                END ) 
                OVER ( 
                  PARTITION BY
                    [client_id]
                  ORDER BY 
                    [dt] 
                  ROWS BETWEEN
                        UNBOUNDED PRECEDING
                    AND CURRENT ROW )
  FROM
    h1
),
h3 AS (
  SELECT
    [client_id],
    [dt_e] = [dt],
    [dt_s] = LAG( [dt] ) 
              OVER ( 
                PARTITION BY 
                  [client_id]
                ORDER BY 
                  [dt] ),
    [is_end]
  FROM
    h2
  WHERE
        [is_end] = 0 AND [is_open] = 1
    OR  [is_end] = 1 AND [is_open] = 0
),
h4 AS (
  SELECT
    [client_id],
    [dt_s],
    [dt_e],
    [dt_e_prev] = LAG( [dt_e] ) 
                  OVER (
                    PARTITION BY
                      [client_id]
                    ORDER BY
                      [dt_s] )
  FROM 
    h3
  WHERE
    [is_end] = 1
)
SELECT
  [client_id],
  [dt_e_prev],
  [dt_s],
  [dt_e]
FROM
  h4
WHERE
  DATEDIFF( DAY, [dt_e_prev], [dt_s] ) >= 30
;