use tempdb;
go

create table dbo.t (id int identity primary key, g int, s varchar(100), o int);

insert into dbo.t
 (g, s, o)
 select top (1000000)
  rand(checksum(newid())) * 1000, cast(newid() as varchar(100)), rand(checksum(newid())) * 1000
 from
  master.dbo.spt_values a cross join
  master.dbo.spt_values b;

create index IX_t__g on dbo.t(g) include (s, o);
go

create function dbo.fnStringConcatScalar
(
 @g int
)
returns varchar(max)
as
begin
 declare @result varchar(max) = '';

 select
  @result += ', ' + s
 from
  dbo.t
 where
  g = @g
 order by
  o;

 return @result;
end;
go

create function dbo.fnStringConcatInline
(
 @g int
)
returns table
as
return (
 select stuff((
   select ', ' + s from dbo.t where g = @g order by o for xml path(''), type
  ).value('.', 'varchar(max)'), 1, 2, '') as result
);
go

declare @s varchar(max);

set statistics time on;

select
 @s = dbo.fnStringConcatScalar(a.g)
from
 (select distinct g from dbo.t) a
option
 (maxdop 1);

select
 @s = b.result
from
 (select distinct g from dbo.t) a cross apply
 dbo.fnStringConcatInline(a.g) b
option
 (maxdop 1);

set statistics time off;
go

drop function dbo.fnStringConcatScalar, dbo.fnStringConcatInline;
drop table dbo.t;
go