declare
	--Максимальный размер в МБ для рассматриваемого объекта
	@ObjectSizeMB numeric (16,3) = NULL,
	--Максимальное кол-во строк в секции
	@row_count numeric (16,3) = NULL

/*
	тонкое обновление статистики
*/
SET NOCOUNT ON;
SET TRANSACTION ISOLATION LEVEL READ UNCOMMITTED;

   declare @ObjectID int;
declare @SchemaName nvarchar(255);
declare @ObjectName nvarchar(255);
declare @StatsID int;
declare @StatName nvarchar(255);
declare @SQL_Str nvarchar(max);

;with st AS(
select DISTINCT 
obj.[object_id]
, obj.[create_date]
, OBJECT_SCHEMA_NAME(obj.[object_id]) as [SchemaName]
, obj.[name] as [ObjectName]
, CAST(
		(
		   --общее число страниц, зарезервированных в секции (по 8 КБ на 1024 поделить=поделить на 128)
			SELECT SUM(ps2.[reserved_page_count])/128.
			from sys.dm_db_partition_stats as ps2
			where ps2.[object_id] = obj.[object_id]
		) as numeric (38,2)
	  ) as [ObjectSizeMB] --размер объекта в МБ
, s.[stats_id]
, s.[name] as [StatName]
, sp.[last_updated]
, i.[index_id]
, i.[type_desc]
, i.[name] as [IndexName]
, ps.[row_count]
, s.[has_filter]
, s.[no_recompute]
, sp.[rows]
, sp.[rows_sampled]
--кол-во изменений вычисляется как:
--сумма общего кол-ва изменений в начальном столбце статистики с момента последнего обновления статистики
--и разности приблизительного кол-ва строк в секции и общего числа строк в таблице или индексированном представлении при последнем обновлении статистики
, sp.[modification_counter]+ABS(ps.[row_count]-sp.[rows]) as [ModificationCounter]
--% количества строк, выбранных для статистических вычислений,
--к общему числу строк в таблице или индексированном представлении при последнем обновлении статистики
, NULLIF(CAST( sp.[rows_sampled]*100./sp.[rows] as numeric(18,3)), 100.00) as [ProcSampled]
--% общего кол-ва изменений в начальном столбце статистики с момента последнего обновления статистики
--к приблизительному количество строк в секции
, CAST(sp.[modification_counter]*100./(case when (ps.[row_count]=0) then 1 else ps.[row_count] end) as numeric (18,3)) as [ProcModified]
--Вес объекта:
--[ProcModified]*десятичный логарифм от приблизительного кол-ва строк в секции
, CAST(sp.[modification_counter]*100./(case when (ps.[row_count]=0) then 1 else ps.[row_count] end) as numeric (18,3))
							* case when (ps.[row_count]<=10) THEN 1 ELSE LOG10 (ps.[row_count]) END as [Func]
--было ли сканирование:
--общее количество строк, выбранных для статистических вычислений, не равно
--общему числу строк в таблице или индексированном представлении при последнем обновлении статистики
, CASE WHEN sp.[rows_sampled]<>sp.[rows] THEN 0 ELSE 1 END as [IsScanned]
, tbl.[name] as [ColumnType]
, s.[auto_created]	
from sys.objects as obj
inner join sys.stats as s on s.[object_id] = obj.[object_id]
left outer join sys.indexes as i on i.[object_id] = obj.[object_id] and (i.[name] = s.[name] or i.[index_id] in (0,1) 
				and not exists(select top(1) 1 from sys.indexes i2 where i2.[object_id] = obj.[object_id] and i2.[name] = s.[name]))
left outer join sys.dm_db_partition_stats as ps on ps.[object_id] = obj.[object_id] and ps.[index_id] = i.[index_id]
outer apply sys.dm_db_stats_properties (s.[object_id], s.[stats_id]) as sp
left outer join sys.stats_columns as sc on s.[object_id] = sc.[object_id] and s.[stats_id] = sc.[stats_id]
left outer join sys.columns as col on col.[object_id] = s.[object_id] and col.[column_id] = sc.[column_id]
left outer join sys.types as tbl on col.[system_type_id] = tbl.[system_type_id] and col.[user_type_id] = tbl.[user_type_id]
where obj.[type_desc] <> 'SYSTEM_TABLE'
)
SELECT
	st.[object_id]
	, st.[SchemaName]
	, st.[ObjectName]
	, st.[stats_id]
	, st.[StatName]
	INTO #tbl
FROM st
WHERE NOT (st.[row_count] = 0 AND st.[last_updated] IS NULL)--если нет данных и статистика не обновлялась
	--если нечего обновлять
	AND NOT (st.[row_count] = st.[rows] AND st.[row_count] = st.[rows_sampled] AND st.[ModificationCounter]=0)
	--если есть что обновлять (и данные существенно менялись)
	AND ((st.[ProcModified]>=10.0) OR (st.[Func]>=10.0) OR (st.[ProcSampled]<=50))
	--ограничения, выставленные во входных параметрах
	AND (
		 ([ObjectSizeMB]<=@ObjectSizeMB OR @ObjectSizeMB IS NULL)
		 AND
		 (st.[row_count]<=@row_count OR @row_count IS NULL)
		);

WHILE (exists(select top(1) 1 from #tbl))
BEGIN
	select top(1)
	@ObjectID	=[object_id]
	,@SchemaName=[SchemaName]
	,@ObjectName=[ObjectName]
	,@StatsId	=[stats_id]
	,@StatName	=[StatName]
	from #tbl;

	SET @SQL_Str = 'IF (EXISTS(SELECT TOP(1) 1 FROM sys.stats as s WHERE s.[object_id] = '+CAST(@ObjectID as nvarchar(32)) + 
					' AND s.[stats_id] = ' + CAST(@StatsId as nvarchar(32)) +')) UPDATE STATISTICS ' + QUOTENAME(@SchemaName) +'.' +
					QUOTENAME(@ObjectName) + ' ('+QUOTENAME(@StatName) + ') WITH FULLSCAN;';

	execute sp_executesql @SQL_Str;

	delete from #tbl
	where [object_id]=@ObjectID
	  and [stats_id]=@StatsId;
END

drop table #tbl;

set nocount on;

declare @db table (db varchar(128))
create  table #files
	(
	Drive varchar(10),
	DBName varchar(128),
	FileType varchar(10),
	LogicalName varchar(128),
	PhysicalName varchar(512),
	SizeMB numeric(10,2),
	Comment varchar(128),
	[FileGroup] varchar(128),
	SpaceUsedMB numeric(10,2),
	SpaceFreeMB numeric(10,2),
	[Status] varchar(50),
	MaxSizeMB varchar(20),
	Growth varchar(20),
	FileID smallint
	)
declare @d varchar(128)
declare @cmd varchar(4096)

insert into @db (db)
select name 
from sys.databases
where is_in_standby<>1
and DATABASEPROPERTYEX(name,'Status')='ONLINE'

while exists (select top 1 1 from @db)
	begin
		select top 1 @d=db from @db 

		set @cmd='use ['+@d+'];'
		set @cmd=@cmd+'select 
							left(physical_name,3) [Drive]
							,db_name() [DBName]
							,type_desc [FileType]
							,name [LogicalName]
							,physical_name
							,size/128. [SizeMB]
							,state_desc [comment]
							,case when data_space_id=0 then '''' 
							else (select name+N'' (''+type_desc+N'')'' collate SQL_Latin1_General_CP1_CI_AS from sys.data_spaces where data_space_id=df.data_space_id) end [FileGroup]

							,CAST(FILEPROPERTY(df.name, ''SpaceUsed'') AS int)/128. [SpaceUsedMB]
							,size/128.0 - CAST(FILEPROPERTY(df.name, ''SpaceUsed'') AS int)/128. AS [SpaceFreeMB]

							,df.state_desc as [Status]

							,case 
								when df.max_size=-1 then ''Unlimited''
								else convert(varchar(50),ceiling(df.max_size/128.)) end as [MaxSizeMB]

							,case 
								when df.is_percent_growth=1 then convert(varchar(20),df.growth)+''%''
								else 
								convert(varchar(20),convert(int,df.growth/128.))+'' MB'' end as [Growth]
							, df.file_id
						from sys.database_files df 
						
						option (recompile)'

		insert into #files (Drive,DBName,FileType,LogicalName,PhysicalName,SizeMB,Comment,[FileGroup],SpaceUsedMB,SpaceFreeMB,[Status],MaxSizeMB,Growth,FileID)
		exec (@cmd)

		set @cmd=''
		delete from @db where db=@d
	end

select 
	Drive
	,DBName
	,FileType
	,LogicalName
	,PhysicalName
	,SizeMB
	,Comment
	,[FileGroup]
	,SpaceUsedMB
	,SpaceFreeMB
	,[Status]
	,MaxSizeMB
	,Growth
	,FileID
from #files