Добро пожаловать в форум, Guest  >>   Войти | Регистрация | Поиск | Правила | В избранное | Подписаться
Все форумы / Delphi Новый топик    Ответить
Топик располагается на нескольких страницах: [1] 2   вперед  Ctrl      все
 Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
Есть функция подсчета количества файлов в паке с подпапками для Windows
Function GetDocsCount(Dir: String; count: integer): integer;
Var
 SearchRec: TSearchRec;
begin
//добавляем все найденные файлы в таблицу
 try
   if Dir <> '' then Dir := IncludeTrailingPathDelimiter(Dir);
   if FindFirst(Dir + '*.*', faAnyFile, SearchRec) = 0 then
     repeat
       if (SearchRec.name='.') or
          (SearchRec.name='..') or
          (AnsiUpperCase(SearchRec.name) = AnsiUpperCase(sThumbnailFileName)) or
          (SearchRec.Name = '') then continue;
       if ((SearchRec.Attr and faDirectory) <> 0) then
         count := GetDocsCount(Dir + SearchRec.name, count) //we found Directory: "Dir+SearchRec.name"
       else
         begin
           Inc(count);
           
         end;

     until FindNext(SearchRec) <> 0;

 finally
   FindClose(SearchRec);
 end;
 result := count;
end;


А как эта функция будет "выглядеть" для Линукса?
Как ее переписать для Линукса?
17 июл 20, 09:44    [22169031]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
wadman
Member

Откуда: Санкт-Петербург
Сообщений: 26714
В линуксах не работает System.IOUtils?
17 июл 20, 09:47    [22169034]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
Я не знаю, я ещё ни разу не писал под линукс, примеров не нашёл.
17 июл 20, 09:53    [22169041]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
Начинаю припоминать....
http://docwiki.embarcadero.com/RADStudio/Sydney/en/Standard_RTL_Path_Functions_across_the_Supported_Target_Platforms

с Андроидом немного работал
17 июл 20, 09:58    [22169047]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
Vizit0r
Member

Откуда: Одесса
Сообщений: 805
X11
Я не знаю, я ещё ни разу не писал под линукс, примеров не нашёл.


а ты ищи примеры работы с классами из System.IOUtils - они мультиплатфоменные все.
17 июл 20, 10:03    [22169050]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
Нашел такое
http://docwiki.embarcadero.com/Libraries/Rio/en/System.IOUtils.TSearchOption
http://docwiki.embarcadero.com/CodeExamples/Rio/en/DirectoriesAndFilesEnumeraion_(Delphi)
http://docwiki.embarcadero.com/Libraries/Rio/en/System.IOUtils.TDirectory.GetFiles


Я так подразумеваю, что код будет такой:
Function GetDocsCount(Dir: String): integer;
begin
  result := Length(TDirectory.GetFiles(dir, '.', TSearchOption.soAllDirectories));
end;
17 июл 20, 10:13    [22169059]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
Fr0sT-Brutal
Member

Откуда:
Сообщений: 344
А откуда ты взял, что в Линуксе это не будет работать?
function FindFirst(const Path: string; Attr: Integer;
  var F: TSearchRec): Integer;
const
  faSpecial = faHidden or faSysFile or faDirectory;
{$IFDEF MSWINDOWS}
...
{$ENDIF MSWINDOWS}
{$IFDEF POSIX}
...
{$ENDIF POSIX}
17 июл 20, 10:23    [22169075]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
1. Ни откуда не взял, просто предположил.
2. Модуль System.IOUtils более новый, т.е. продвинутый, современный. Думаю, что его более правильно использовать.
17 июл 20, 10:25    [22169078]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
Вопрос по маске
GetFiles(dir, '*.JPEG *.BMP *.PNG *.GIF', TSearchOption.soAllDirectories)


Как правильно ввести маску для поиска нескольких разных типов?
В документации описано только то, что якобы можно использовать только *.exe - т.е. один тип.
Как правильно? Через запятую, через пробел? Или вообще нельзя мульти маску использовать?
17 июл 20, 10:28    [22169080]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
X11
Через запятую, через пробел?


Методом научного тыка определил, что можно через точку с запятой. Но это для винды, а для Линукса?
17 июл 20, 10:30    [22169083]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
wadman
Member

Откуда: Санкт-Петербург
Сообщений: 26714
X11
X11
Через запятую, через пробел?


Методом научного тыка определил, что можно через точку с запятой. Но это для винды, а для Линукса?

GetFiles написан на дельфи. На кой его писать отдельно для каждой платформы?

Но исходники дадут более точный ответ.
17 июл 20, 10:33    [22169085]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
Fr0sT-Brutal
Member

Откуда:
Сообщений: 344
X11
1. Ни откуда не взял, просто предположил.
2. Модуль System.IOUtils более новый, т.е. продвинутый, современный. Думаю, что его более правильно использовать.

Эти вещи просто более модная обертка над все теми же функциями из SysUtils
17 июл 20, 11:09    [22169109]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
Fr0sT-Brutal
Эти вещи просто более модная обертка над все теми же функциями из SysUtils


судя по исходникам, - нет
17 июл 20, 11:35    [22169125]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
http://docwiki.embarcadero.com/Libraries/Rio/en/System.IOUtils.TDirectory.TFilterPredicate

ну на крайний случай можно свою функцию (анонимную) написать, которая будет определять, включать ли файл в массив
17 июл 20, 11:35    [22169126]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
wadman
Но исходники дадут более точный ответ.


посмотрел, добрался до TMask.MatchesMaskStates(), так и не понял, какой разделитель используется, если вообще его там можно использовать
17 июл 20, 11:38    [22169128]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
тут огромная статья с примерами
http://www.proghouse.ru/programming/126-ioutils
17 июл 20, 12:10    [22169152]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
X11
X11
Через запятую, через пробел?


Методом научного тыка определил, что можно через точку с запятой. Но это для винды, а для Линукса?


В общем, так
GetFiles(dir, '*.JPEG *.BMP *.PNG *.GIF', TSearchOption.soAllDirectories)

не работает
17 июл 20, 12:20    [22169163]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
Dimitry Sibiryakov
Member

Откуда:
Сообщений: 50816

X11
А как эта функция будет "выглядеть" для Линукса?
Как ее переписать для Линукса?

Не надо никак переписывать. SysUtils под линухом полностью функционален "как есть".

Posted via ActualForum NNTP Server 1.5

17 июл 20, 12:32    [22169177]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
В общем, вот так получилось:

uses System.IOUtils, System.Types;
....

const cFileMaskImages = '*.JPG;*.JPEG;*.BMP;*.PNG;*.GIF';


....
implementation

uses
  System.SysUtils, System.Masks, System.StrUtils;

function GetListDocs(Dir: String): TStringDynArray;
var
 Predicate: TDirectory.TFilterPredicate;
 MaskArray: TStringDynArray;
begin
  MaskArray := SplitString(cFileMaskImages, ';');

  Predicate :=
    function(const Path: string; const SearchRec: TSearchRec): Boolean
    var
      Mask: string;
    begin
      for Mask in MaskArray do
        if MatchesMask(SearchRec.Name, Mask) then
          exit(True);
      exit(False);
    end;


  result := TDirectory.GetFiles(dir, '*', TSearchOption.soAllDirectories, Predicate);
end;
17 июл 20, 12:35    [22169179]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
Fr0sT-Brutal
Member

Откуда:
Сообщений: 344
X11
Fr0sT-Brutal
Эти вещи просто более модная обертка над все теми же функциями из SysUtils


судя по исходникам, - нет

Не знаю, как судишь исходники ты, но я вижу вот это
class procedure TDirectory.WalkThroughDirectory(const Path, Pattern: string;
  const PreCallback, PostCallback: TDirectoryWalkProc;
  const Recursive: Boolean);
var
  SearchRec: TSearchRec;
  Match: Boolean;
  Stop: Boolean;
begin
  if FindFirst(TPath.DoCombine(Path, '*', False), faAnyFile, SearchRec) = 0 then // DO NOT LOCALIZE
  ...
20 июл 20, 10:21    [22170242]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
Интересно, почему разработчики в TFile не добавили метод GetFileSize()?
22 июл 20, 11:49    [22171593]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
X11
Интересно, почему разработчики в TFile не добавили FileSize()?
22 июл 20, 11:49    [22171594]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
wadman
Member

Откуда: Санкт-Петербург
Сообщений: 26714
"Дорого"... Оставили на следующие релизы.

Может это поможет? http://docwiki.embarcadero.com/Libraries/Rio/en/System.IOUtils.TDirectory.TFilterPredicate
22 июл 20, 11:55    [22171598]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
Сделал так, надеюсь и для Линукса в будущем прокатит
function GetFileSize(const FileName: String): Int64;
var
  f: file of Byte;
begin
  try
    AssignFile(f, FileName);
    Reset(f);
    result := FileSize(f);
  finally
    CloseFile(f);
  end;
end;


Сообщение было отредактировано: 22 июл 20, 11:59
22 июл 20, 12:00    [22171602]     Ответить | Цитировать Сообщить модератору
 Re: Аналог TSearchRec, FindFirst, FindNext под Линукс  [new]
X11
Member

Откуда: Kharkiv, Ukraine
Сообщений: 14302
читаю комменты
http://www.malcolmgroves.com/blog/?p=447

ещё 10 лет назад просили добавить

К сообщению приложен файл. Размер - 39Kb


Сообщение было отредактировано: 22 июл 20, 12:06
22 июл 20, 12:07    [22171607]     Ответить | Цитировать Сообщить модератору
Топик располагается на нескольких страницах: [1] 2   вперед  Ctrl      все
Все форумы / Delphi Ответить