Добро пожаловать в форум, Guest  >>   Войти | Регистрация | Поиск | Правила | В избранное | Подписаться
Все форумы / FoxPro, Visual FoxPro Новый топик    Ответить
 Запомнить установки VFP  [new]
q1w1e1
Member

Откуда: Кы-рск
Сообщений: 1034
Есть ли какая-нибудь функция, которая бы запоминала текущее состояние VFP, чтоб после тестирования программы(которая меняет установки), и возврата в командное окно VFP, можно было бы эти установки возратить в исходное состояние...ну типа функция set("установка"), конечно подходит..но не будешь же заводить сто переменных для запоминания этих установок...
28 мар 08, 12:03    [5472278]     Ответить | Цитировать Сообщить модератору
 Re: Запомнить установки VFP  [new]
12345вышелзайчикпогулять
Guest
https://www.sql.ru/forum/actualthread.aspx?tid=510872&hl=%ee%ea%ed%ee+options

читаем это

автор

Часть настроек среды FoxPro можно увидеть через пункт меню Tools, подпункт Options. А чтобы получить эти настройки в виде кодов нажмите и удерживайте клавишу "Shift" и левой кнопкой мыши нажмите на кнопку "Ok". В командное окно будет выведены все текущие настройки формы Options. В версии VFP9 список настроек будет выведен в окно Output окна Debugger.

Далее просто копируете эти настройки, оформляете их как файл PRG, выбрасывая лишнее и дописывая недостающее. Затем выполняете этот PRG в новой копии.

Чтобы сделанные настройки остались и после перезагрузки среды FoxPro надо в окне Options нажать кнопку "Set as Default"
28 мар 08, 12:10    [5472349]     Ответить | Цитировать Сообщить модератору
 Re: Запомнить установки VFP  [new]
q1w1e1
Member

Откуда: Кы-рск
Сообщений: 1034
спасибо, но например в программе открываю форму, для этого я запоминаю в переменную
_del=set("deleted"), во время работы set deleted меняется в различных ветках много раз, в зависимости от ситуации, но на выходе я должен его восстановить как было, но помимо
set deleted есть и set date to german и т.д., много разных set(ов), которые меняют свои значения, т.е. нет установленных в начале программы set(ов), они динамично меняются..., вот и думал может можно set(ы) сохранить в массиве на входе и и восстановить на выходе(ну не всегда можно уследить, где что изменил), программно, без копирования (display status to file) в файл и оформления в статистические переменные...
28 мар 08, 13:32    [5473044]     Ответить | Цитировать Сообщить модератору
 Re: Запомнить установки VFP  [new]
piva
Member

Откуда: Курган
Сообщений: 1096
Sys(3056)

Все что у тебя в Tools\Options - все восстановит
28 мар 08, 14:00    [5473291]     Ответить | Цитировать Сообщить модератору
 Re: Запомнить установки VFP  [new]
12345вышелзайчикпогулять
Guest
ну раз Вы их дергаете,
то конечно прийдется запоминать
и восстанавливать
где-то у меня валялся код,
который запоминае и восстанавливает
в объект - найду - положу сюда



автор
во время работы set deleted меняется в различных ветках много раз


поросто для информации,
прошу дискуссию не начинать

придерживаюсь мнения, что такой подход имеет право на жизнь

set deleted off

create cursor tt (id i autoinc, value c(10))
index on deleted() tag del binary
index on !deleted() tag notdel binary

for i=1 to 10
	insert into tt (value) values (ltrim(str(i)))
	delete from tt where id=getautoincvalue()
	insert into tt (value) values (ltrim(str(i)))
endfor

select * ;
	from tt ;
	where !deleted()
	
select * ;
	from tt ;
	where deleted()

set deleted - это тормоз (на больших объемах),
который лучше не включать
но это требует опред.квалификации от разработчика
28 мар 08, 14:04    [5473312]     Ответить | Цитировать Сообщить модератору
 Re: Запомнить установки VFP  [new]
ВладимирМ
Member

Откуда: г. Москва
Сообщений: 7864
Создай класс на базе Custom, в INIT которого запоминаешь текущие настройки, записывая в свойства класса, а в Destroy этого же класса восстанавливай. Далее бросаешь экземпляр этого класса на форму и все. Разумеется, если не делаешь настройки в LOAD-формы или в событиях DataEnvironment.
28 мар 08, 14:41    [5473581]     Ответить | Цитировать Сообщить модератору
 Re: Запомнить установки VFP  [new]
q1w1e1
Member

Откуда: Кы-рск
Сообщений: 1034
Чёрт, ввёл в дебугере Watch команду Sys(3056), чтоб посмотреть а что будет..., блин всё зависло, все окошки задрожали и комп отрубился...кое как опять до инета достучался..., а поподробней про метод инит в классе как всё запоминается...как бросается класс на форму...
28 мар 08, 14:52    [5473653]     Ответить | Цитировать Сообщить модератору
 Re: Запомнить установки VFP  [new]
12345вышелзайчикпогулять
Guest
************************************************************
* Method: CGlobalEnvironment.SaveOldSettings() - CENVIRON.VCX
*
*) Description:
*) Saves the settings of the environment so they can
*) be reset later.
*
*@ Inputs: None
*
* Outputs:
* 1. Way too numerous to list here, look at the code below.
*
*$ Usage:
*$ <objectname>.SaveOldSettings()
*
*% Example:
*% This.SaveOldSettings() - see CEnvironment.Init()
*
* Returns: LOGICAL .T. by default
* Assumptions: None
* Rules: None
* Constraints:
* Performance: None
* Enviornmental: None
*? Notes: None
* Local Routines:
* 1. CEnvironment::SaveOldSettings()
*
*-- Process:
*-- 1. Call the superclass Init() method
*-- 2. Save the values initially stored in global variables.
*-- 3. Save the rest of the settings.
*
* Change Log:
* CREATED Sunday, 11/05/95 12:40:56 - CTB:
* MODIFIED Monday, 10/06/98 21:29:00 - CTB:
* 06.01.0002 - modified to cater to OLE servers
* just in case the global variables are not defined.
* Included based on suggestions from Dan Welter.
************************************************************
*---------------------------------------------------
*-- Call the superclass method just in case somebody
*-- modified the behavior of the CEnvironment class
*---------------------------------------------------
DODEFAULT()

WITH This
	*-------------
	*-- 06.01.0002
	*--------------------------------------
	*-- Initial values set from global vars
	*--------------------------------------
	.cOldTalk = IIF( TYPE("gcOldTalk") == "C" , gcOldTalk , SET('TALK'))
	.cOldClassLib = IIF( TYPE("gcOldClassLib") == "C" , gcOldClassLib , SET('CLASSLIB'))
	.cOldDir = IIF( TYPE("gcOldDir") == "C" , gcOldDir , FULLPATH(CURDIR()))
	.cOldPath = IIF( TYPE("gcOldPath") == "C" , gcOldPath , SET('PATH'))
	.cOldProcedure = IIF( TYPE("gcOldProcedure") == "C" , gcOldProcedure , SET('PROCEDURE'))

	*$dpw$*--12/18/97
	*-- Updated to take advantage of OLE servers. Just in case
	*-- the global variables aren't defined.
	*!* .cOldTalk = gcOldTalk
	*!* .cOldClassLib = gcOldClassLib
	*!* .cOldDir = gcOldDir
	*!* .cOldPath = gcOldPath
	*!* .cOldProcedure = gcOldProcedure


	*---------------------------------------
	*-- Initial values set from SET commands
	*---------------------------------------
	.cOldAlternate = SET('ALTERNATE')
	.cOldAlternateTo = SET('ALTERNATE', 1)
	.cOldAplAbout = SET('APLABOUT')
	.cOldAplAboutPrompt = SET('APLABOUT', 1)
	.cOldBell = SET('BELL')
	.cOldBlink = SET('BLINK')
	.cOldBrstatus = SET('BRSTATUS')
	.cOldClear = SET('CLEAR')
	.cOldClock = SET('CLOCK')
	.cOldCompatible = SET('COMPATIBLE')
	.cOldConsole = SET('CONSOLE')
	.nOldCPCompile = SET('CPCOMPILE')
	.cOldCpdialog = SET('CPDIALOG')
	.cOldCursor = SET('CURSOR')
	.cOldDebug = SET('DEBUG')
	.cOldDevelopment = SET('DEVELOPMENT')
	.cOldDevice = SET('DEVICE')
	.cOldDoHistory = SET('DOHISTORY')
	.cOldDoHistoryTo = SET('DOHISTORY', 1)
	.cOldEcho = SET('ECHO')
	.cOldEscape = SET('ESCAPE')
	.nOldFdow = SET('FDOW')
	.cOldFormat = SET('FORMAT')
	.cOldFullpath = SET('FULLPATH')
	.nOldFWeek = SET('FWEEK')
	.cOldHeadings = SET('HEADINGS')
	.cOldHelp = SET('HELP')
	.cOldHelpTo = SET('HELP', 1)
	.cOldHelpFilter = SET('HELPFILTER')
	*** EGL: 05/22/1999 - Moved this property to the cSessionEnvironment class.
	*!*	.nOldHours = SET('HOURS')
	.cOldIntensity = SET('INTENSITY')
	.cOldKeycomp = SET('KEYCOMP')
	.cOldLibrary = SET('LIBRARY')
	.cOldLogerrors = SET('LOGERRORS')
	.cOldMacDesktop = SET('MACDESKTOP')
	.cOldMacHelp = SET('MACHELP')
	.cOldMacHelpPrompt = SET('MACHELP', 1)
	.cOldMacKey = SET('MACKEY')
	.nOldMargin = SET('MARGIN')
	.cOldNotify = SET('NOTIFY')
	.nOldOdometer = SET('ODOMETER')
	.cOldOleObject = SET('OLEOBJECT')
	.cOldOptimize = SET('OPTIMIZE')
	.cOldPalette = SET('PALETTE')
	.cOldPrinter = SET('PRINTER')
	.cOldPrinterTo = SET('PRINTER', 1)
	.cOldReadBorder = SET('READBORDER')
	*** EGL: 05/22/1999 - Moved this property to the cSessionEnvironment class.
	*!*	.nOldRefresh = SET('REFRESH')
	.cOldResource = SET('RESOURCE')
	.cOldResourceTo = SET('RESOURCE', 1)
	.cOldScoreboard = SET('SCOREBOARD')
	.cOldShadows = SET('SHADOWS')
	.cOldSpace = SET('SPACE')
	.cOldStatus = SET('STATUS')
	.cOldStatusBar = SET('STATUS BAR')
	.cOldSticky = SET('STICKY')
	.cOldTextmerge = SET('TEXTMERGE')
	.cOldTextmergeDelimiters = SET('TEXTMERGE', 1)
	.cOldTopic = SET('TOPIC')
	.cOldTopicId = SET('TOPIC ID')
	.nOldTypeahead = SET('TYPEAHEAD')
	.cOldUdfparms = SET('UDFPARMS')

ENDWITH

RETURN



библиотеки дать?
или сам сделаешь?
28 мар 08, 15:23    [5473857]     Ответить | Цитировать Сообщить модератору
 Re: Запомнить установки VFP  [new]
12345вышелзайчикпогулять
Guest
это метод восстановления

************************************************************
*   Method:  CGlobalEnvironment.Set() - CENVIRON.VCX
*
*)  Description:
*)    Sets the global environment to the specified settings
*
*@  Inputs: None
*   Outputs: None
*$  Usage:
*$    <objectname>.Set()
*
*%  Example:
*%    .Set() - see CEnvironment::Init()
*
*   Returns:  LOGICAL .T. by default
*   Assumptions: None
*   Rules:  None
*   Constraints:
*     Performance: None
*     Enviornmental: None
*?  Notes:
*?
*?    1.  The application object is used in this method
*?        in order to access the GetSetting() method which
*?        allows the retrieval of user specified set values.
*?
*?    2.  IF we are in debug mode the following SET commnads
*?        are set to ON ...
*?            DEVELOPMENT, ESCAPE, DEBUG, LOGERRORS
*?
*?    3.  TO DEVELOPERS ... if you want to use VFP default
*?            values just leave the properties blank.  To
*?            override the default values, fill in the
*?            appropriate value in the desired property.
*?
*   Local Routines:
*     1.  IsA() - in UTILITY.PRG
*     2.  CEnvironment::Set()
*
*-- Process:
*--   1.  IF this object has a parent
*--   2.     Determine if its parent is an application object
*--   3.     Store a local reference to the application object
*--       ENDIF
*--   4.  Determine if we are in debug mode.
*--   5.  Call the superclass Init() method
*--
*   Change Log:
*       CREATED Sunday, 11/05/95 13:05:06 - CTB:
************************************************************
LOCAL llAppIsPresent, ;
	loApp, ;
	llDebugMode, ;
	luTemp

*---------------------------------------------------------
*           LOCAL/PRIVATE VARIABLE DESCRIPTIONS
*---------------------------------------------------------
* llAppIsPresent - stores whether or not this object
*             is a child of an application object.
* loApp - reference to the global application object
* llDebugMode - stores whether or not this application
*               is being run in debug mode.  If we are
*               in debug mode ensure SET DEVELOPMENT is ON
*               otherwise set it OFF.  Same with SET
*               ESCAPE, SET DEBUG, SET LOGERRORS
* luTemp - temporary variable used to store the value
*          of the setting so it can be set using
*          macro substitution.
*---------------------------------------------------------

WITH This
	*!*	IF TYPE(".Parent") == "O"
	IF TYPE(".Parent.Name") == "C"
		*--------------------------------------------------
		*-- Determine if the parent of this object is the
		*-- global application object.
		*--------------------------------------------------
		llAppIsPresent = IsA(.Parent, "CApplication")

		*-----------------------------------------------
		*-- Store a reference to the application object.
		*-----------------------------------------------
		loApp = .Parent
	ENDIF
ENDWITH

*--------------------------------------------------
*-- Determine if the application is in debug mode
*--------------------------------------------------
llDebugMode = FILE(DEBUGMODEFILE)

*--------------------------------------------------
*-- Call the superclass method just in case someone
*-- changed the behavior of the CEnvironment class
*--------------------------------------------------
*** EGL: 05/22/1999 - Changed this to DODEFAULT() to respect the i-layer
*!*	CEnvironment::Set()
DODEFAULT()

WITH This
	*--------------------------------------------------
	*-- Set the settings to the specified values.
	*--------------------------------------------------
	IF EMPTY(.cAlternate)
		SET ALTERNATE OFF
	ELSE
		luTemp = .cAlternate
		SET ALTERNATE &luTemp
	ENDIF

	IF EMPTY(.cAlternateTo)
		SET ALTERNATE TO
	ELSE
		luTemp = .cAlternateTo
		SET ALTERNATE TO &luTemp
	ENDIF

	IF EMPTY(.cAplAbout)
		SET APLABOUT DISABLED
	ELSE
		luTemp = .cAplAbout
		SET APLABOUT &luTemp
	ENDIF

	IF EMPTY(.cAplAboutPrompt)
		SET APLABOUT PROMPT
	ELSE
		luTemp = .cAplAboutPrompt
		SET APLABOUT PROMPT &luTemp
	ENDIF

	IF EMPTY(.cBell)
		luTemp = "ON"

		*-------------------------------------------------------------
		*-- Try to initialize from wherever system settings are stored
		*-------------------------------------------------------------
		IF llAppIsPresent
			luTemp = loApp.GetSetting("On Off Settings", "SET BELL", "ON")
		ENDIF
		SET BELL &luTemp

	ELSE
		luTemp = .cBell
		SET BELL &luTemp
	ENDIF

	IF EMPTY(.cBlink)
		SET BLINK OFF
	ELSE
		luTemp = .cBlink
		SET BLINK &luTemp
	ENDIF

	IF EMPTY(.cBrstatus)
		SET BRSTATUS OFF
	ELSE
		luTemp = .cBrstatus
		SET BRSTATUS &luTemp
	ENDIF

	IF EMPTY(.cClear)
		SET CLEAR ON
	ELSE
		luTemp = .cClear
		SET CLEAR &luTemp
	ENDIF

	IF EMPTY(.cClock)
		luTemp = "STATUS"
		*-------------------------------------------------------------
		*-- Try to initialize from wherever system settings are stored
		*-------------------------------------------------------------
		IF llAppIsPresent
			luTemp = loApp.GetSetting("On Off Settings", "SET CLOCK", "STATUS")
		ENDIF
		luTemp = IIF(luTemp = "ON", "STATUS", luTemp)
		SET CLOCK &luTemp
	ELSE
		luTemp = .cClock
		SET CLOCK &luTemp
	ENDIF

	IF EMPTY(.cCompatible)
		SET COMPATIBLE FOXPLUS
	ELSE
		luTemp = .cCompatible
		SET COMPATIBLE &luTemp
	ENDIF

	IF EMPTY(.cConsole)
		IF SET('CONSOLE') = 'OFF'
			SET CONSOLE ON
		ENDIF
	ELSE
		luTemp = .cConsole
		SET CONSOLE &luTemp
	ENDIF

	IF EMPTY(.nCPCompile)
		SET CPCOMPILE TO 1252
	ELSE
		SET CPCOMPILE TO .nCPCompile
	ENDIF

	IF EMPTY(.cCpdialog)
		SET CPDIALOG OFF
	ELSE
		luTemp = .cCpdialog
		SET CPDIALOG &luTemp
	ENDIF

	IF EMPTY(.cCursor)
		SET CURSOR ON
	ELSE
		luTemp = .cCursor
		SET CURSOR &luTemp
	ENDIF

	IF EMPTY(.cDebug)
		IF llDebugMode
			SET DEBUG ON
		ELSE
			SET DEBUG OFF
		ENDIF
	ELSE
		luTemp = .cDebug
		SET DEBUG &luTemp
	ENDIF

	IF EMPTY(.cDevelopment)
		IF llDebugMode
			SET DEVELOPMENT ON
		ELSE
			SET DEVELOPMENT OFF
		ENDIF
	ELSE
		luTemp = .cDevelopment
		SET DEVELOPMENT &luTemp
	ENDIF

	IF EMPTY(.cDevice)
		SET DEVICE TO SCREEN
	ELSE
		luTemp = .cDevice
		SET DEVICE TO &luTemp
	ENDIF

	IF EMPTY(.cDoHistory)
		SET DOHISTORY OFF
	ELSE
		luTemp = .cDoHistory
		SET DOHISTORY &luTemp
	ENDIF

	IF EMPTY(.cDoHistoryTo)
		SET DOHISTORY TO
	ELSE
		luTemp = .cDoHistoryTo
		SET DOHISTORY TO &luTemp
	ENDIF

	IF EMPTY(.cEcho)
		SET ECHO OFF
	ELSE
		luTemp = .cEcho
		SET ECHO &luTemp
	ENDIF

	IF EMPTY(.cEscape)
		IF llDebugMode
			SET ESCAPE ON
		ELSE
			SET ESCAPE OFF
		ENDIF
	ELSE
		luTemp = .cEscape
		SET ESCAPE &luTemp
	ENDIF

	IF EMPTY(.nFdow)
		SET FDOW TO 1
	ELSE
		SET FDOW TO .nFdow
	ENDIF

	IF EMPTY(.cFormat)
		SET FORMAT TO
	ELSE
		luTemp = .cFormat
		SET FORMAT TO &luTemp
	ENDIF

	IF EMPTY(.cFullpath)
		SET FULLPATH ON
	ELSE
		luTemp = .cFullpath
		SET FULLPATH &luTemp
	ENDIF

	IF EMPTY(.nFWeek)
		SET FWEEK TO 1
	ELSE
		SET FWEEK TO .nFWeek
	ENDIF

	IF EMPTY(.cHeadings)
		SET HEADINGS ON
	ELSE
		luTemp = .cHeadings
		SET HEADINGS &luTemp
	ENDIF

	IF EMPTY(.cHelp)
		SET HELP ON
	ELSE
		luTemp = .cHelp
		SET HELP &luTemp
	ENDIF

	*** EGL: 05/28/1999 - Added check for llAppIsPresent
	*--{06/30/97 PDH MM 2.0 Bldg on QS Proj, Step 9
	*IF EMPTY(.cHelpTo)
	*!*	IF EMPTY(loApp.cHelpFileName)
	IF NOT llAppIsPresent OR EMPTY(loApp.cHelpFileName)
		IF FILE(HOME() + "FOXHELP.HLP")
			SET HELP TO
		ENDIF
	ELSE
		luTemp = loApp.cHelpFileName
		IF FILE(loApp.cHelpFileName)
			SET HELP TO &luTemp
		ENDIF
	ENDIF

	IF EMPTY(.cHelpFilter)
		SET HELPFILTER TO
	ELSE
		luTemp = .cHelpFilter
		SET HELPFILTER TO &luTemp
	ENDIF

	*** EGL: 05/22/1999 - Moved this property to the cSessionEnvironment class.
	*!*	IF EMPTY(.nHours)
	*!*	  SET HOURS TO 12
	*!*	ELSE
	*!*	  SET HOURS TO .nHours
	*!*	ENDIF

	IF EMPTY(.cIntensity)
		SET INTENSITY ON
	ELSE
		luTemp = .cIntensity
		SET INTENSITY &luTemp
	ENDIF

	IF EMPTY(.cKeycomp)
		SET KEYCOMP TO WINDOWS
	ELSE
		luTemp = .cKeycomp
		SET KEYCOMP TO &luTemp
	ENDIF

	IF EMPTY(.cLibrary)
		SET LIBRARY TO
	ELSE
		luTemp = .cLibrary
		SET LIBRARY TO &luTemp
	ENDIF

	IF EMPTY(.cLogerrors)
		IF llDebugMode
			SET LOGERRORS ON
		ELSE
			SET LOGERRORS OFF
		ENDIF
	ELSE
		luTemp = .cLogerrors
		SET LOGERRORS &luTemp
	ENDIF

	IF EMPTY(.cMacDesktop)
		SET MACDESKTOP OFF
	ELSE
		luTemp = .cMacDesktop
		SET MACDESKTOP &luTemp
	ENDIF

	IF EMPTY(.cMacHelp)
		SET MACHELP DISABLED
	ELSE
		luTemp = .cMacHelp
		SET MACHELP &luTemp
	ENDIF

	IF EMPTY(.cMacHelpPrompt)
		SET MACHELP PROMPT
	ELSE
		luTemp = .cMacHelpPrompt
		SET MACHELP PROMPT &luTemp
	ENDIF

	IF EMPTY(.cMacKey)
		SET MACKEY TO SHIFT+F10
	ELSE
		luTemp = .cMacKey
		SET MACKEY TO &luTemp
	ENDIF

	IF EMPTY(.nMargin)
		SET MARGIN TO 0
	ELSE
		SET MARGIN TO .nMargin
	ENDIF

	IF EMPTY(.cNotify)
		SET NOTIFY OFF
	ELSE
		luTemp = .cNotify
		SET NOTIFY &luTemp
	ENDIF

	IF EMPTY(.nOdometer)
		SET ODOMETER TO 100
	ELSE
		SET ODOMETER TO .nOdometer
	ENDIF

	IF EMPTY(.cOleObject)
		SET OLEOBJECT ON
	ELSE
		luTemp = .cOleObject
		SET OLEOBJECT &luTemp
	ENDIF

	IF EMPTY(.cOptimize)
		SET OPTIMIZE ON
	ELSE
		luTemp = .cOptimize
		SET OPTIMIZE &luTemp
	ENDIF

	IF EMPTY(.cPalette)
		SET PALETTE ON
	ELSE
		luTemp = .cPalette
		SET PALETTE &luTemp
	ENDIF

	IF EMPTY(.cPrinter)
		SET PRINTER OFF
	ELSE
		luTemp = .cPrinter
		SET PRINTER &luTemp
	ENDIF

	IF EMPTY(.cPrinterTo)
		SET PRINTER TO PRN
	ELSE
		luTemp = .cPrinterTo
		SET PRINTER TO &luTemp
	ENDIF

	IF EMPTY(.cReadBorder)
		SET READBORDER OFF
	ELSE
		luTemp = .cReadBorder
		SET READBORDER &luTemp
	ENDIF

	*** EGL: 05/22/1999 - Moved this property to the cSessionEnvironment class.
	*!*	IF EMPTY(.nRefresh)
	*!*	  SET REFRESH TO 0
	*!*	ELSE
	*!*	  SET REFRESH TO .nRefresh
	*!*	ENDIF

	IF EMPTY(.cScoreboard)
		IF SET('SCOREBOARD') = 'ON'
			SET SCOREBOARD OFF
		ENDIF
	ELSE
		luTemp = .cScoreboard
		SET SCOREBOARD &luTemp
	ENDIF

	IF EMPTY(.cShadows)
		SET SHADOWS ON
	ELSE
		luTemp = .cShadows
		SET SHADOWS &luTemp
	ENDIF

	IF EMPTY(.cSpace)
		SET SPACE ON
	ELSE
		luTemp = .cSpace
		SET SPACE &luTemp
	ENDIF

	IF EMPTY(.cStatus)
		IF SET('STATUS') = 'ON'
			SET STATUS OFF
		ENDIF
	ELSE
		luTemp = .cStatus
		SET STATUS &luTemp
	ENDIF

	IF EMPTY(.cStatusBar)
		IF SET('STATUS BAR') = 'OFF'
			SET STATUS BAR ON
		ENDIF
	ELSE
		luTemp = .cStatusBar
		SET STATUS BAR &luTemp
	ENDIF

	IF EMPTY(.cSticky)
		SET STICKY ON
	ELSE
		luTemp = .cSticky
		SET STICKY &luTemp
	ENDIF

	IF EMPTY(.cTalk)
		SET TALK OFF
	ELSE
		luTemp = .cTalk
		SET TALK &luTemp
	ENDIF

	IF EMPTY(.cTextmerge)
		SET TEXTMERGE OFF
	ELSE
		luTemp = .cTextmerge
		SET TEXTMERGE &luTemp
	ENDIF

	IF EMPTY(.cTextmergeDelimiters)
		SET TEXTMERGE DELIMITERS <<>>
	ELSE
		luTemp = .cTextmergeDelimiters
		SET TEXTMERGE DELIMITERS &luTemp
	ENDIF

	IF EMPTY(.cTopic)
		SET TOPIC TO
	ELSE
		luTemp = .cTopic
		SET TOPIC TO &luTemp
	ENDIF

	IF EMPTY(.cTopicId)
		SET TOPIC ID TO
	ELSE
		luTemp = .cTopicId
	ENDIF

	IF EMPTY(.nTypeahead)
		SET TYPEAHEAD TO 25
	ELSE
		SET TYPEAHEAD TO .nTypeahead
	ENDIF

	IF EMPTY(.cUdfparms)
		SET UDFPARMS VALUE
	ELSE
		luTemp = .cUdfparms
		SET UDFPARMS &luTemp
	ENDIF

ENDWITH

RETURN
28 мар 08, 15:25    [5473862]     Ответить | Цитировать Сообщить модератору
 Re: Запомнить установки VFP  [new]
q1w1e1
Member

Откуда: Кы-рск
Сообщений: 1034
спасибо, сейчас поразбираюсь,
28 мар 08, 15:32    [5473914]     Ответить | Цитировать Сообщить модератору
Все форумы / FoxPro, Visual FoxPro Ответить